For your ESP8266 NodeMCU board, this tutorial shows how to set a static/fixed IP address. If you're using your ESP8266 to run a web server or a Wi-Fi client and every time you restart it, it gets a new IP address, you may use this tutorial to assign a static/fixed IP address.

Static/Fixed IP Address Sketch

We'll use the ESP8266 Web Server code as an example to show you how to fix your ESP8266 IP address. You should be able to fix your IP address by the conclusion of our discussion, regardless of the web server or Wi-Fi project you're working on.

Copy the following code to your Arduino IDE, but do not upload it yet. To make it work for you, you'll need to make some changes.

Note: If you upload the next sketch to your ESP8266 board, it should assign the fixed IP address 192.168.1.184 automatically.

/*********
  LEDEdit PRO
  Complete project details at https://lededitpro.com/esp8266-nodemcu-static-fixed-ip-address/
*********/

// Load Wi-Fi library
#include <ESP8266WiFi.h>

// Replace with your network credentials
const char* ssid     = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output5State = "off";
String output4State = "off";

// Assign output variables to GPIO pins
const int output5 = 5;
const int output4 = 4;

// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0; 
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;

// Set your Static IP address
IPAddress local_IP(192, 168, 1, 184);
// Set your Gateway IP address
IPAddress gateway(192, 168, 1, 1);

IPAddress subnet(255, 255, 0, 0);
IPAddress primaryDNS(8, 8, 8, 8);   //optional
IPAddress secondaryDNS(8, 8, 4, 4); //optional

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output5, OUTPUT);
  pinMode(output4, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output5, LOW);
  digitalWrite(output4, LOW);
  
  // Configures static IP address
  if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
    Serial.println("STA Failed to configure");
  }
  
  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    currentTime = millis();
    previousTime = currentTime;
    while (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
      currentTime = millis();         
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /5/on") >= 0) {
              Serial.println("GPIO 5 on");
              output5State = "on";
              digitalWrite(output5, HIGH);
            } else if (header.indexOf("GET /5/off") >= 0) {
              Serial.println("GPIO 5 off");
              output5State = "off";
              digitalWrite(output5, LOW);
            } else if (header.indexOf("GET /4/on") >= 0) {
              Serial.println("GPIO 4 on");
              output4State = "on";
              digitalWrite(output4, HIGH);
            } else if (header.indexOf("GET /4/off") >= 0) {
              Serial.println("GPIO 4 off");
              output4State = "off";
              digitalWrite(output4, LOW);
            }
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>ESP8266 Web Server</h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 5  
            client.println("<p>GPIO 5 - State " + output5State + "</p>");
            // If the output5State is off, it displays the ON button       
            if (output5State=="off") {
              client.println("<p><a href=\"/5/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/5/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
            // Display current state, and ON/OFF buttons for GPIO 4  
            client.println("<p>GPIO 4 - State " + output4State + "</p>");
            // If the output4State is off, it displays the ON button       
            if (output4State=="off") {
              client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Setting Your Network Credentials

You need to modify the following lines with your network's SSID and password.

// Replace with your network credentials
const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

Setting ESP8266 Static IP Address

Then, outside of the setup() and loop() procedures declare the following variables with your own static IP address and gateway IP address:

The next code, by default, assigns the IP address 192.168.1.184, which works with the gateway 192.168.1.1.

// Set your Static IP address
IPAddress local_IP(192, 168, 1, 184);
// Set your Gateway IP address
IPAddress gateway(192, 168, 1, 1);

IPAddress subnet(255, 255, 0, 0);
IPAddress primaryDNS(8, 8, 8, 8); // optional
IPAddress secondaryDNS(8, 8, 4, 4); // optional

Important: On your local network, you need to use the corresponding gateway and an available IP address.

setup()

You need to assign the configurations to your ESP8266 in setup() by using WiFi.config() method.

// Configures static IP address
if (!WiFi.config(local_IP, gateway, subnet, primaryDNS, secondaryDNS)) {
  Serial.println("STA Failed to configure");
}

Note: the “primaryDNS” and “secondaryDNS“ parameters are optional and you can remove them.

Testing

After uploading the code to your board, open the Arduino IDE Serial Monitor at 115200 baud rate, restart your ESP8266 board, and the IP address you specified earlier should be assigned to your board.

ESP8266 Fixed Static IP Address Serial Monitor

As you can see, it prints the IP address 192.168.1.184.

To assign a fixed IP address to your ESP8266, you may take this example and add it to all of your Wi-Fi sketches.

Assigning IP Address with MAC Address

If you tried using the previous example to assign a fixed IP address to the ESP8266 and it didn't work, we recommend assigning an IP address directly in your router settings using the ESP8266 MAC Address.

Upload the following code to the ESP8266 board:

// Complete Instructions to Get and Change ESP MAC Address: https://lededitpro.com/get-mac-address-of-esp32-esp8266-arduino-ide/

#ifdef ESP32
  #include <WiFi.h>
#else
  #include <ESP8266WiFi.h>
#endif

void setup(){
  Serial.begin(115200);
  Serial.println();
  Serial.print("ESP Board MAC Address:  ");
  Serial.println(WiFi.macAddress());
}
 
void loop(){

}

It prints the ESP8266 MAC Address on the Serial Monitor in setup():

// Print ESP MAC Address
Serial.println("MAC address: ");
Serial.println(WiFi.macAddress());

In our example, the MAC Address of the ESP8266 is “B4:E6:2D:97:EE:F1“. You'll need the MAC Address in just a bit, so copy it.

Router Settings

When you login to your router's admin page, you should see a page or menu where you can assign an IP address to a network device. Each router has its own set of menus and configurations. As a result, we are unable to give instructions for all available routers.

ELEGOO UNO R3 2.8 Inches TFT Touch Screen with SD...

Sale

Official Arduino Starter Kit [K000007] (English...

ELEGOO Mega R3 Project The Most Complete Ultimate...

We recommend searching “assign IP address to MAC address” followed by the name of your router. You should be able to find some instructions that show you how to assign an IP address to a MAC address for your specific router.

In summary, you should be able to assign your desired IP address to your ESP8266 MAC address (for example, B4:E6:2D:97:EE:F1) by going to your router's configuration menu.

Conclusion

You should be able to assign a fixed/static IP address to your ESP8266 after following this tutorial. If you own an ESP32, you should read this guide: Set ESP32 Static/Fixed IP Address.

Sale