In this project, you'll use the Arduino IDE to build a standalone web server with an ESP8266 that can toggle two LEDs. Any device with a browser on your local network may visit this ESP8266 Web Server since it is mobile-responsive. Using Arduino IDE, build an ESP8266 web server.

For a more in-depth tutorial on how to create a web server and an explanation of the code, read this post: Build an ESP8266 Web Server: The Complete Guide

If you want to learn more about the ESP8266 module, first read my Getting Started with ESP8266 NodeMCU Board | Complete Guide

Uploading the ESP8266 code

Go to “Tools” and select “Generic ESP8266 Module” if you already have the ESP8266 add-on for the Arduino IDE installed (see How to Install ESP8266 Board in Arduino IDE in less than 1 minute).

Freenove Ultimate Starter Kit for ESP32-WROVER...

SunFounder ESP32 Ultimate Starter Kit (Compatiple...

Freenove Development Kit for ESP32-S3 (Compatible...

Add the following sketch to your Arduino IDE: With your network credentials, replace the SSID and password.

const char* ssid = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

Upload the new sketch to your ESP8266 after modifying it. Read this troubleshooting guide if you can't upload code to your ESP8266.

/*********
  LEDEdit PRO
  Complete project details at https://lededitpro.com  
*********/

// Load Wi-Fi library
#include <ESP8266WiFi.h>

// Replace with your network credentials
const char* ssid     = "REPLACE_WITH_YOUR_SSID";
const char* password = "REPLACE_WITH_YOUR_PASSWORD";

// Set web server port number to 80
WiFiServer server(80);

// Variable to store the HTTP request
String header;

// Auxiliar variables to store the current output state
String output5State = "off";
String output4State = "off";

// Assign output variables to GPIO pins
const int output5 = 5;
const int output4 = 4;

// Current time
unsigned long currentTime = millis();
// Previous time
unsigned long previousTime = 0; 
// Define timeout time in milliseconds (example: 2000ms = 2s)
const long timeoutTime = 2000;

void setup() {
  Serial.begin(115200);
  // Initialize the output variables as outputs
  pinMode(output5, OUTPUT);
  pinMode(output4, OUTPUT);
  // Set outputs to LOW
  digitalWrite(output5, LOW);
  digitalWrite(output4, LOW);

  // Connect to Wi-Fi network with SSID and password
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Print local IP address and start web server
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop(){
  WiFiClient client = server.available();   // Listen for incoming clients

  if (client) {                             // If a new client connects,
    Serial.println("New Client.");          // print a message out in the serial port
    String currentLine = "";                // make a String to hold incoming data from the client
    currentTime = millis();
    previousTime = currentTime;
    while (client.connected() && currentTime - previousTime <= timeoutTime) { // loop while the client's connected
      currentTime = millis();         
      if (client.available()) {             // if there's bytes to read from the client,
        char c = client.read();             // read a byte, then
        Serial.write(c);                    // print it out the serial monitor
        header += c;
        if (c == '\n') {                    // if the byte is a newline character
          // if the current line is blank, you got two newline characters in a row.
          // that's the end of the client HTTP request, so send a response:
          if (currentLine.length() == 0) {
            // HTTP headers always start with a response code (e.g. HTTP/1.1 200 OK)
            // and a content-type so the client knows what's coming, then a blank line:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();
            
            // turns the GPIOs on and off
            if (header.indexOf("GET /5/on") >= 0) {
              Serial.println("GPIO 5 on");
              output5State = "on";
              digitalWrite(output5, HIGH);
            } else if (header.indexOf("GET /5/off") >= 0) {
              Serial.println("GPIO 5 off");
              output5State = "off";
              digitalWrite(output5, LOW);
            } else if (header.indexOf("GET /4/on") >= 0) {
              Serial.println("GPIO 4 on");
              output4State = "on";
              digitalWrite(output4, HIGH);
            } else if (header.indexOf("GET /4/off") >= 0) {
              Serial.println("GPIO 4 off");
              output4State = "off";
              digitalWrite(output4, LOW);
            }
            
            // Display the HTML web page
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS to style the on/off buttons 
            // Feel free to change the background-color and font-size attributes to fit your preferences
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #195B6A; border: none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color: #77878A;}</style></head>");
            
            // Web Page Heading
            client.println("<body><h1>ESP8266 Web Server</h1>");
            
            // Display current state, and ON/OFF buttons for GPIO 5  
            client.println("<p>GPIO 5 - State " + output5State + "</p>");
            // If the output5State is off, it displays the ON button       
            if (output5State=="off") {
              client.println("<p><a href=\"/5/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/5/off\"><button class=\"button button2\">OFF</button></a></p>");
            } 
               
            // Display current state, and ON/OFF buttons for GPIO 4  
            client.println("<p>GPIO 4 - State " + output4State + "</p>");
            // If the output4State is off, it displays the ON button       
            if (output4State=="off") {
              client.println("<p><a href=\"/4/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/4/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");
            
            // The HTTP response ends with another blank line
            client.println();
            // Break out of the while loop
            break;
          } else { // if you got a newline, then clear currentLine
            currentLine = "";
          }
        } else if (c != '\r') {  // if you got anything else but a carriage return character,
          currentLine += c;      // add it to the end of the currentLine
        }
      }
    }
    // Clear the header variable
    header = "";
    // Close the connection
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Upload code to ESP8266-01

You need an FTDI programmer to upload the code if you're using an ESP8266-01. As shown in the following schematic diagram, connect the ESP8266 to the FTDI programmer.

FREENOVE Ultimate Starter Kit for ESP8266...

Freenove Super Starter Kit for ESP8266 (Included)...

ALAMSCN ESP8266 IoT Electronics Starter Kit,...

ESP8266 IP Address

Open the Arduino serial monitor at a baud rate of 115200.

If you’re using ESP8266-01, connect GPIO 0 to VCC and reset your board.
If you’re using ESP8266-12E, just press the RESET button.

After a few seconds, the ESP8266 IP address should appear.

Parts List

This is the hardware you'll need to complete this project:

GeeekPi Raspberry Pi 4 8GB Starter Kit - 128GB...

GeeekPi Raspberry Pi 4 4GB Kit - 64GB Edition,...

Vilros Raspberry Pi 4 Complete Starter Kit-...

You can use the preceding links to find all the parts for your projects at the best price!

Final Circuit

Build the circuit you'll be controlled using the following schematic diagram. One LED is connected to GPIO 4(D2), and the other to GPIO 5(D1).

If you're using the ESP8266-01, you may use the following schematic diagram as a guide, but you'll need to change the GPIO assignments in the code (to GPIO 2 and GPIO 0).

Sale